Qbasicnews.com

QbasicNews.Com => Challenges => Topic started by: wildcard on August 31, 2002, 11:59:54 AM



Title: New Challenge Forum
Post by: wildcard on August 31, 2002, 11:59:54 AM
Welcome to the new challenge forum. There will be a weekly or bi-weekly challenges. Each challenge will require different skills to the previous ones. So for the first challenge I've let it be decided by a poll for the type of challenge.

Each challenge should not take long to complete but there will be no maximum time allowed(therefore take as much time as you need).


Title: New Challenge Forum
Post by: wildcard on September 01, 2002, 01:35:37 PM
The poll seems to show a game but it'll only finish within 6 more days, after then the challenge will be posted.


Title: New Challenge Forum
Post by: Neo on September 02, 2002, 05:15:07 AM
You can also do a GFX-Demo compo.

Making a graphical or sound demo. (Or somethin' else).

-Neo


Title: New Challenge Forum
Post by: LooseCaboose on September 02, 2002, 05:41:35 AM
Im a bit of a geek so I like the more mathy challenges.

I dont know how many people would be interested but you could hold an obfuscated qb code contest. The object is to create a complete program that does something, but is almost impossible to understand. www.ioccc.org hold an obfuscated C code contest every year (I have a half finished entry).

I have done some cool coding challenges where you have to write a program (usually only a few lines) to perform a certain task, but with heavy constraints (such as only being allowed one for-loop or not using some statements), this really challenge peoples ability to use a language to its fullest.

Just my 2 cents


Title: New Challenge Forum
Post by: Neo on September 02, 2002, 07:08:57 AM
Writing very complex programs, that do something simple, sound good  :bounce: !

-Neo


Title: New Challenge Forum
Post by: wizardlife on September 02, 2002, 01:55:46 PM
Well, if you intend us to finish it within a week or two, it'll have to be relatively simple. I recommend that most or all of the challenges be pureQB. That way there isn't preference to one library (since often one is more appropriate than another in a particular situation -- eg. DirectQB has more functions like rotation and scaling and so on, but RelLib is faster.)

I also propose that rather than having really general stuff like 'make a cool minigame', give very specific direction like 'make a platformer that sidescrolls in Screen 12 and involves a multiple on-screen projectile weapon, and allows the player to perform at least five basic operations: Left, Right, Jump, Duck, and Fire.

Evaluation should be on a per-contest basis. As in, a different rubric for each time around. Fun Factor, Graphics, and GUI might be categories in a game, but in a graphical demo, it might be more like Ingenuity, First Impression, and Attention to Detail.

Finally, having a contest every single week isn't necessarily a good idea. Particularly with us all going back to school this week. For the example I laid out above, a more realistic deadline would be two or three months down the road. But that doesn't mean the forum would have to fall silent for that time: Each entrant could start a thread for their project and then post updates and screenshots and whatever other hype material.

Just my suggestions.


Title: New Challenge Forum
Post by: na_th_an on September 02, 2002, 02:03:32 PM
I vote for wizardlife's suggestions.

Also I challenge you all to write a short program which inputs your name and writes "Hello, "+name$ on screen without using PRINT, INPUT nor INKEY$. C'mon!!


Title: New Challenge Forum
Post by: wildcard on September 02, 2002, 03:57:31 PM
Agreed, I'm aimimg for different aspects for each challenge. I think I'll move them to a monthly or bi-monthly minimum(time isn't always freely available, I know).


Title: New Challenge Forum
Post by: na_th_an on September 03, 2002, 11:01:47 AM
Oh - Nobody even tried... Here's my sollution :D :D :D

The input routine needs much improvement as it doesn't still support all the keys nor CAPS / ALT+GR combinations, but, oh well, I coded this straight from scratch in ten minutes... Don't ask me more :D

Code:

DECLARE SUB myLocate (xx%, yy%)
DECLARE FUNCTION myInput$ ()
DECLARE SUB NL ()
DECLARE SUB myPrint (a$)
DECLARE SUB myCls ()
DECLARE SUB ScrollScreen ()
' Write an INPUT "what's your name";a$:PRINT "Hello "+a$ program without
' using INPUT nor PRINT nor INKEY$

DIM SHARED myPrintX%, myPrintY%
DIM SHARED kc$(127)      ' Far from complete

DIM SHARED MaxKey%

myCls

tecladata:
kc$(1) = CHR$(27)
kc$(2) = "1"
kc$(3) = "2"
kc$(4) = "3"
kc$(5) = "4"
kc$(6) = "5"
kc$(7) = "6"
kc$(8) = "7"
kc$(9) = "8"
kc$(10) = "9"
kc$(11) = "0"
kc$(12) = "-"
kc$(13) = "+"
kc$(14) = CHR$(8)

kc$(15) = CHR$(9)
kc$(16) = "q"
kc$(17) = "w"
kc$(18) = "e"
kc$(19) = "r"
kc$(20) = "t"
kc$(21) = "y"
kc$(22) = "u"
kc$(23) = "i"
kc$(24) = "o"
kc$(25) = "p"
kc$(26) = "{"
kc$(27) = "}"
kc$(28) = CHR$(13)

kc$(29) = CHR$(0)
kc$(30) = "a"
kc$(31) = "s"
kc$(32) = "d"
kc$(33) = "f"
kc$(34) = "g"
kc$(35) = "h"
kc$(36) = "j"
kc$(37) = "k"
kc$(38) = "l"
kc$(39) = ":"
kc$(40) = CHR$(34)
kc$(41) = "~"

kc$(42) = CHR$(0)
kc$(43) = "|"
kc$(44) = "z"
kc$(45) = "x"
kc$(46) = "c"
kc$(47) = "v"
kc$(48) = "b"
kc$(49) = "n"
kc$(50) = "m"
kc$(51) = "<"
kc$(52) = ">"
kc$(53) = "?"
kc$(54) = CHR$(0)

kc$(55) = "*"
kc$(56) = CHR$(0)
kc$(57) = " "
kc$(58) = CHR$(0)
kc$(59) = "F1"
kc$(60) = "F2"
kc$(61) = "F3"
kc$(62) = "F4"
kc$(63) = "F5"
kc$(64) = "F6"
kc$(65) = "F7"
kc$(66) = "F8"
kc$(67) = "F9"

kc$(68) = "F10"
kc$(69) = CHR$(0)
kc$(70) = CHR$(0)

kc$(71) = "7"
kc$(72) = "8"
kc$(73) = "9"
kc$(74) = "-"
kc$(75) = "4"
kc$(76) = "5"
kc$(77) = "6"
kc$(78) = "+"
kc$(79) = "1"
kc$(80) = "2"
kc$(81) = "3"
kc$(82) = "0"
kc$(83) = "."
kc$(84) = "END!"
MaxKey% = 84

myPrint "Enter your name: "
a$ = myInput
NL
myPrint "Hello, " + a$ + "!"

SUB myCls
   myPrintX% = 1
   myPrintY% = 1
   CLS
END SUB

FUNCTION myInput$
   t% = 0
   o$ = ""
   x% = myPrintX%
   y% = myPrintY%
   myLocate x%, y%
   myPrint ">"
   x% = x% + 1
   WHILE NOT t%
      ' Clear buffer
      DEF SEG = &H40
      POKE &H1A, PEEK(&H1C)      ' Head = Tail so clear :)
      DEF SEG
      ' Inp:
      k% = INP(&H60)
      IF k% < MaxKey% THEN
         ch$ = kc$(k%)
         SELECT CASE ch$
            CASE CHR$(8):
               IF LEN(o$) > 0 THEN
                  o$ = LEFT$(o$, LEN(o$) - 1)
               END IF
            CASE CHR$(13):
               t% = -1
            CASE ELSE
               o$ = o$ + ch$
         END SELECT
         WHILE INP(&H60) = k%: WEND    ' Depress
      END IF
      myLocate x%, y%
      myPrint o$ + "_ "
   WEND
   myInput$ = o$
END FUNCTION

SUB myLocate (xx%, yy%)
   myPrintX% = xx%
   myPrintY% = yy%
END SUB

SUB myPrint (a$)
   DEF SEG = &HB800
   FOR i% = 1 TO LEN(a$)
      m$ = MID$(a$, i%, 1)
      POKE (myPrintX% - 1) * 2 + (myPrintY% - 1) * 160, ASC(m$)
      myPrintX% = myPrintX% + 1
      IF myPrintX% = 81 THEN
         myPrintX% = 1
         myPrintY% = myPrintY% + 1
         IF myPrintY% = 26 THEN
            ScrollScreen
            myPrintY% = 25
         END IF
      END IF
   NEXT i%
   DEF SEG
END SUB

SUB NL
   ' CRLF :)
   myPrintX% = 1
   myPrintY% = myPrintY% + 1
   IF myPrintY% = 26 THEN
      ScrollScreen
      myPrintY% = 25
   END IF
END SUB

SUB ScrollScreen
   DEF SEG = &HB800
   FOR y% = 1 TO 24
      FOR x% = 0 TO 79
         POKE (y% - 1) * 160 + x% * 2, PEEK(y% * 160 + x% * 2)
   NEXT x%, y%
   FOR x% = 0 TO 79
      POKE 25 * 160 + x% * 2, 32
   NEXT x%
   DEF SEG
END SUB


Title: New Challenge Forum
Post by: wildcard on September 03, 2002, 06:48:26 PM
Sorry na_th_an but I caused some problems on the site by accident so many people can't access it unless they know to go via http://hybd.net/~qbnews


Title: New Challenge Forum
Post by: na_th_an on September 04, 2002, 08:56:15 AM
Oh, please don't worry about that ;)


Title: New Challenge Forum
Post by: wildcard on September 05, 2002, 09:34:37 PM
Ok, but it is still very frustrating not to be able to access your own site as well as everyone else accessing.


Title: New Challenge Forum
Post by: wizardlife on September 05, 2002, 10:24:00 PM
Yeah, getting stuff on the screen is easy: just POKE it to &hB800. But receiving input is a different story. I would have done it with LINE INPUT or INPUT(1), two keyboard I/O commands you forgot to list.  :king:


Title: New Challenge Forum
Post by: BlueKeyboard on September 08, 2002, 07:12:24 AM
A new challenge:
A program that clears the screen(SCREEN 13), without using any of qb's drawing commands, like PSET, CIRCLE, LINE, CLS(hehe), PUT.
You can't use * or FOR either...
I don't think it's impossible... :D.


Title: New Challenge Forum
Post by: na_th_an on September 08, 2002, 10:21:08 AM
Done: HAHAHAH! :D

Code:

SCREEN 13
PRINT "Hello!"
PRINT "Dummy"
PRINT "Press a key to delete"
SLEEP:K$=INKEY$
SCREEN 13
PRINT "Deleted! :D"


Also

Code:

SCREEN 13:DEF SEG=&HA000
BSAVE "CLS", 0,64000
PRINT "Hello!"
PRINT "Dummy"
PRINT "Press a key to delete"
SLEEP:K$=INKEY$
BLOAD "CLS"
PRINT "Deleted! :D"


Wizardlife: saying INPUT I meant EVERY INPUT commands (INPUT a$, LINE INPUT a$, INPUT(1), INPUT$...) :D ;)  :rotfl:


Title: New Challenge Forum
Post by: wildcard on September 08, 2002, 10:41:53 AM
Quote from: "na_th_an"
Done: HAHAHAH! :D



A bit dubious(sp?) but it does meet the guidelines hehe

Quote from: "na_th_an"

Wizardlife: saying INPUT I meant EVERY INPUT commands (INPUT a$, LINE INPUT a$, INPUT(1), INPUT$...) :D ;)  :rotfl:


Well you can just use INP(61h) or somethhing instead ;-)


Title: New Challenge Forum
Post by: na_th_an on September 08, 2002, 12:27:26 PM
Oh cool :D
Now it's your turn, wizardlife... you should post the new challenge ;)


Title: New Challenge Forum
Post by: BlueKeyboard on September 08, 2002, 12:28:24 PM
awww, forgot BLOAD...  :lol:, ok new guidelines, Challenge ver 2:

all the old ones
BLOAD not allowed
reusing SCREEN 13 or any other screen mode is not allowed

There, I think that's all :bounce: .


Title: New Challenge Forum
Post by: wildcard on September 08, 2002, 03:20:10 PM
Ok, as it seems to be more intresting when many people send in ideas lets do it that way. So PM your challenges and I'll post them one at a time(the author can then post his solution or say which is best.)

So PM or email them to me.


Title: New Challenge Forum
Post by: Hard Rock on September 08, 2002, 03:26:17 PM
Mines the crappiest but...

Code:

Screen 13
Print "watch this cheap ass hack, used to enter a contest"
Print "here goes, im gonna clear the screen"
Print"                                                                              "
Print"                                                                              "
Print"                                                                              "
Print"                                                                              "
Print"                                                                              "
Print"                                                                              "
Print"                                                                              "
Print"                                                                              "
Print"                                                                              "
Print"                                                                              "
Print"                                                                              "
Print"                                                                              "
Print"                                                                              "
Print"                                                                              "
Print"                                                                              "
Print"                                                                              "
Print"                                                                              "
Print"                                                                              "
Print"                                                                              "
Print"                                                                              "


Okay, its slow.... its um very hacky and i didnt check if i put enough prints (i think its 20 that screen 13 has) hope i put enough.[edit] fixed some spelling[/edit]

also you code poke at the screen, and im pretty sure you can hit an interuot to do it for you.


Title: New Challenge Forum
Post by: BlueKeyboard on September 08, 2002, 03:31:55 PM
Hehehehehe, you've done it I guess!!!.
Ok,
1. nathan
2. Hard Rock
3. ???

who will win the 3rd place?, ok here comes challenge ver 3:

Guidelines:

all the old guidelines
PRINT not allowed

Now, I hope I haven't forgotten anything now again... :lol:  :lol:  :lol: .


Title: New Challenge Forum
Post by: na_th_an on September 08, 2002, 03:52:27 PM
A single question... Do you know to do it?  :barf:
Just curiosity :D


Title: New Challenge Forum
Post by: BlueKeyboard on September 08, 2002, 03:53:37 PM
Yes :D


Title: New Challenge Forum
Post by: wildcard on September 08, 2002, 03:57:07 PM
Code:

'$INCLUDE: 'QB.BI'
DIM InAry AS RegType, OutAry AS RegType
InAry.ax = &H13
CALL INTERRUPT(&H10, InAry, OutAry)


Don't forget to use qb/l ;-)


Title: New Challenge Forum
Post by: na_th_an on September 08, 2002, 03:58:58 PM
Quote from: "BlueKeyboard"
You can't use * or FOR either...
I

so what if...

Code:

SCREEN 13
DEF SEG=&HA000
i%=0
WHILE i%<64000
   POKE i%,0
   i%=i%+1
WEND
DEF SEG


Title: New Challenge Forum
Post by: BlueKeyboard on September 08, 2002, 04:05:59 PM
Yup, we have three winners :D:

nathan, Hard Rock and wildcard.

Hmmm, I guess there must be a final:
But only nathan, Hard Rock and wildcard can enter...


Title: New Challenge Forum
Post by: BlueKeyboard on September 08, 2002, 04:13:19 PM
Ok, here comes the final challenge:

Guidelines:
Make a rotating box in the middle of the screen, not a filled box.
It should rotate by itself.

The first to enter that program, wins...


Title: New Challenge Forum
Post by: BlueKeyboard on September 08, 2002, 04:14:14 PM
Quote from: "na_th_an"
Quote from: "BlueKeyboard"
You can't use * or FOR either...
I

so what if...

Code:

SCREEN 13
DEF SEG=&HA000
i%=0
WHILE i%<64000
   POKE i%,0
   i%=i%+1
WEND
DEF SEG


Yup, it is that easy  :D  :D  :D


Title: New Challenge Forum
Post by: wildcard on September 08, 2002, 05:08:52 PM
Pseduo bad entry ;-)

Code:

SCREEN 13

time! = TIMER
DO: del = del + 1: LOOP UNTIL TIMER - time! > .05
time2 = TIMER

FOR i = 0 TO 360
DRAW "M160,100TA" + STR$(i) + "C0L5C0C15U10R10D10L10"
FOR dell = 0 TO del: NEXT dell
WAIT 986, 8
CLS
NEXT i


Title: New Challenge Forum
Post by: BlueKeyboard on September 08, 2002, 05:14:44 PM
wildcard won!!!   :bounce:


Title: New Challenge Forum
Post by: wizardlife on September 08, 2002, 06:20:05 PM
Quote from: "wildcard"
Pseduo bad entry ;-)

Code:

SCREEN 13

time! = TIMER
DO: del = del + 1: LOOP UNTIL TIMER - time! > .05
time2 = TIMER

FOR i = 0 TO 360
DRAW "M160,100TA" + STR$(i) + "C0L5C0C15U10R10D10L10"
FOR dell = 0 TO del: NEXT dell
WAIT 986, 8
CLS
NEXT i


lol. that works, I guess. I read it as 'cube', not 'box', though... started digging up my trig rotations. sin and cos...


Title: New Challenge Forum
Post by: Hard Rock on September 08, 2002, 07:10:59 PM
Wow..... someone actually knows how to use the DRAW command......

[edit] oh hey, 100 posts..... do i get money or anything?[/edit]


Title: New Challenge Forum
Post by: wildcard on September 08, 2002, 07:29:03 PM
Yeah, I prefer to take the easiest/simplest apporach ;-) 2D rotating.. 3d would probably have gone down well.

Quote
Wow..... someone actually knows how to use the DRAW command......


Back in my day... before we had libraries.. hehe nah I think I've just used qb for ages and have messed around a lot(hence no projects/products of mine available). The DRAW command can be very useful albeit annoying ;-)


Title: New Challenge Forum
Post by: na_th_an on September 08, 2002, 09:17:30 PM
hahaha can you believe it? I first used the DRAW command instead of PUT for sprites HAHAHAHAHHAA I'll look for the code to show it to you.

ANd I only had a 486DX2/66Mhz running uncompiled QBasic 1.1... Imagine the speed :D

heh, I mean BITMAP SPRITES!!


Title: New Challenge Forum
Post by: wizardlife on September 08, 2002, 10:06:48 PM
Hey... I first used GW-basic on my dad's Business Depot fodder 486-33. And I tried to make it display some sprites with Draw, too. They were a six cell monochromatic animation of a man running that I found in a (really, really) old book.


Title: New Challenge Forum
Post by: BlueKeyboard on September 09, 2002, 09:10:06 AM
Actually, a qb book I read, didn't even cover the put statement..., it seemed to focus more on using lines and circles :rotfl:...


Title: New Challenge Forum
Post by: na_th_an on September 09, 2002, 09:56:54 AM
Heh it is really weird. I had an editor which placed the cursor in the middle of the screen and opened a file for output. You could be in drawing mode or moving mode. You could move in 8 directions using the keys Q W E D C X Z A. When you pressed the numbers or shift+number you could choose a colour.

It worked this way: If you pressed "A" (LEFT), a "L1" was added to the file. If you pressed "E" (UP RIGHT), a "E1" was added to your file. If you pressed "SHIFT+6" (LIGHT YELLOW), a "C14" was added to your file. If you were in drawing mode, the strings were written without alter, but if you were in moving mode a "B" was put before the commands.

Then, in your game, you opened the file and loaded its contents to a variable, say o$. Everytime you wanted to draw a sprite, you PRESET to the position and called a DRAW o$.

It is the weirdest way to draw a sprite that I've seen... Still looking for the code.

Anyhow, now that we are on this topic: Let's write the weirdest PUT (bitmaps) replacement! I'll post mine (explained above) when I find it, or maybe when I recode it.


Title: New Challenge Forum
Post by: na_th_an on September 09, 2002, 10:44:05 AM
Oh - I should be editing... I forgot that there are people who hate double posts :D :D just kidding. Well, I found something. And I consider that it is cleaner to post it separately. It is sumthing like this:

The Editor

Code:

x% = 0
y% = 0
SCREEN 7
PRINT "Your drawing will be saved to a file."
PRINT "You may press 'S' to close the file and"
PRINT "EXIT."
INPUT "File Name"; n$
CLS
PAINT (0, 0), 15
OPEN n$ FOR OUTPUT AS #1
LINE (128, 0)-(128, 128), 0
LINE (0, 128)-(128, 128), 0
mode% = 0   ' Not Drawing
c% = 0
oc% = POINT(8 * x%, 8 * y%)
COLOR 7
LOCATE 19, 1: PRINT " MOVE:QWEDCXZA         "
LOCATE 20, 1: PRINT " COL:[SHIFT]+12345670  "
LOCATE 21, 1: PRINT " ENTER:DRAW|SPACE:MOVE "
DO
 
   IF NOT mode% THEN
      LINE (8 * x%, 8 * y%)-(7 + 8 * x%, 7 + 8 * y%), oc%, BF
   ELSE
      LINE (8 * x%, 8 * y%)-(7 + 8 * x%, 7 + 8 * y%), c%, BF
   END IF
 
   k$ = UCASE$(INKEY$)
   SELECT CASE k$
      CASE "W":
         IF y% > 0 THEN
            IF NOT mode% THEN PRINT #1, "B";
            PRINT #1, "U1";
            y% = y% - 1
         END IF
      CASE "E":
         IF y% > 0 AND x% < 15 THEN
            IF NOT mode% THEN PRINT #1, "B";
            PRINT #1, "E1";
            y% = y% - 1
            x% = x% + 1
         END IF
      CASE "D":
         IF x% < 15 THEN
            IF NOT mode% THEN PRINT #1, "B";
            PRINT #1, "R1";
            x% = x% + 1
         END IF
      CASE "C":
         IF x% < 15 AND y% < 15 THEN
            IF NOT mode% THEN PRINT #1, "B";
            PRINT #1, "F1";
            x% = x% + 1
            y% = y% + 1
         END IF
      CASE "X":
         IF y% < 15 THEN
            IF NOT mode% THEN PRINT #1, "B";
            PRINT #1, "D1";
            y% = y% + 1
         END IF
      CASE "Z":
         IF y% < 15 AND x% > 0 THEN
            IF NOT mode% THEN PRINT #1, "B";
            PRINT #1, "G1";
            x% = x% - 1
            y% = y% + 1
         END IF
      CASE "A":
         IF x% > 0 THEN
            IF NOT mode% THEN PRINT #1, "B";
            PRINT #1, "L1";
            x% = x% - 1
         END IF
      CASE "Q":
         IF x% > 0 AND y% > 0 THEN
            IF NOT mode% THEN PRINT #1, "B";
            PRINT #1, "H1";
            x% = x% - 1
            y% = y% - 1
         END IF
      CASE CHR$(13):
         mode% = -1
      CASE " ":
         mode% = 0
      CASE "1" TO "7", "0": c% = VAL(k$): PRINT #1, "C" + k$;
      ' This is mapped for Spanish keyboard.
      ' These are the symbols which can be gotten pressing the
      ' keys 1-7 and 0 with Shift.
      ' Change for your keyboard layout.
      CASE "!": c% = 9: PRINT #1, "C9";
      CASE CHR$(34): c% = 10: PRINT #1, "C10";' ["] character = 34.
      CASE "": c% = 11: PRINT #1, "C11";
      CASE "$": c% = 12: PRINT #1, "C12";
      CASE "%": c% = 13: PRINT #1, "C13";
      CASE "&": c% = 14: PRINT #1, "C14";
      CASE "/": c% = 15: PRINT #1, "C15";
      CASE "=": c% = 8: PRINT #1, "C8";
      CASE "S": EXIT DO       ' GOTO Fin, originally

   END SELECT

   oc% = POINT(8 * x%, 8 * y%)
   IF mode% THEN
      LINE (8 * x%, 8 * y%)-(7 + 8 * x%, 7 + 8 * y%), c%, BF
      LINE (8 * x%, 8 * y%)-(7 + 8 * x%, 7 + 8 * y%), 15 - c%, B
   ELSE
      LINE (8 * x%, 8 * y%)-(7 + 8 * x%, 7 + 8 * y%), 15 - oc%, B
   END IF

LOOP
Fin:
CLOSE #1
SYSTEM


The SUB which draws it

Code:

DECLARE SUB SCRPUT (x%, y%, o$)
' SPRPUT.BAS
SCREEN 7
INPUT "Sprite filename"; sp$
OPEN sp$ FOR INPUT AS #1
LINE INPUT #1, o$
PRINT "DRAW COMMAND:"
PRINT o$
PRINT : PRINT "PRESS A KEY"
SLEEP: k$ = INKEY$: CLS : PAINT (0, 0), 15
CLOSE #1
WHILE INKEY$ = ""
x% = INT(RND * 320)
y% = INT(RND * 200)
SCRPUT x%, y%, o$
WEND

SUB SCRPUT (x%, y%, o$)
   PRESET (x%, y%)
   DRAW o$
END SUB


Sample sprite
(Cut and paste to notepad, REMOVE THE LINE BREAKS [it should be in ONE SINGLE LINE!!] then save it as sprite.spr, and load it from the previous code) (I've broken the lines 'cause the whole thing screwed the forum layout)

Code:

BF1BF1BF1BF1BR1BR1BR1BU1BL1R1R1R1D1L1C12L1L1D1L1R1R1
R1D1L1L1U1U1C7R1C10C12R1C7F1C8D1D1C4F1F1R1L1H1H1L1
L1L1G1L1H1H1F1F1R1E1R1D1D1D1R1U1U1R1D1D1D1C2L1L1G1
G1D1D1C6L1L1R1U1R1C2U1E1E1R1R1D1D1F1R1C6R1D1U1U1


Weird, isn't it?


Title: New Challenge Forum
Post by: BlueKeyboard on September 09, 2002, 01:39:18 PM
Yeah...


Title: New Challenge Forum
Post by: BlueKeyboard on September 09, 2002, 03:20:04 PM
I made a weird kind of put routine once, it used "compressed" sprites...
It wasn't working very good, though :lol:.
I can't find the code for it...


Title: New Challenge Forum
Post by: BlueKeyboard on September 09, 2002, 03:20:40 PM
wow!!!!!, I'm a Guru!!!!  :D  :D  :D  :D


Title: New Challenge Forum
Post by: wildcard on September 09, 2002, 04:44:00 PM
Quote from: "BlueKeyboard"
wow!!!!!, I'm a Guru!!!!  :D  :D  :D  :D

Not for much longer ;-) heh


Title: New Challenge Forum
Post by: BlueKeyboard on September 09, 2002, 06:33:02 PM
Cooooool, "Surfing Keyboard" :D


Title: New challenge
Post by: LooseCaboose on September 09, 2002, 07:23:03 PM
Heres a challenge for your skills at programming. Hopefully this isnt too easy and yes I do have a solution for this already:

You are to write a program that has a produces a textmode triangle for any given number i. The output should look like the following:

i = 3
#
##
###
##
#

The trick is you are only allowed one loop(for, while, etc) and one if statement, you cannot use anything else (such as switch, else, etc). You also cannot use hardware calls such as peek and poke.
BTW, I think the peek/poke challenges are a bit boring because they test hardware knowledge rather than programming skill. *Ducks and covers*
 :roll:


Title: New Challenge Forum
Post by: wildcard on September 09, 2002, 07:41:04 PM
I've locked this topic and started a new thread for the current challenge. Otherwise this thread would become enourmous. I'll make another thread for you to post your challenges in and I'll post them one by one.